Power BI Time Intelligence for the Indian Financial Year (April–March)

📎 This article includes 2 downloadable practice files ↓

Power BI’s time functions assume a January-December year by default. Indian businesses report April to March, so FY-to-date, quarters and month order all need a little setup. Do it once in the Calendar and every report gets it right.

1. A Calendar table with FY columns

One row per date covering all your data, related to the fact table’s date. In DAX (Modeling › New table):

Calendar =
ADDCOLUMNS (
    CALENDAR ( DATE ( 2024, 4, 1 ), DATE ( 2026, 3, 31 ) ),
    "FYStart", YEAR ( [Date] ) - IF ( MONTH ( [Date] ) < 4, 1, 0 ),
    "FY", "FY " & ( YEAR ( [Date] ) - IF ( MONTH ( [Date] ) < 4, 1, 0 ) ) & "-" & RIGHT ( YEAR ( [Date] ) - IF ( MONTH ( [Date] ) < 4, 1, 0 ) + 1, 2 ),
    "FYMonthNo", MOD ( MONTH ( [Date] ) + 8, 12 ) + 1,
    "Month", FORMAT ( [Date], "mmm" ),
    "FYQuarter", "Q" & INT ( MOD ( MONTH ( [Date] ) + 8, 12 ) / 3 ) + 1
)

Then Mark as date table on the Date column, and set Month › Sort by column › FYMonthNo so April comes first.

2. FY-to-date

Sales FYTD = TOTALYTD ( [Total Sales], Calendar[Date], "31/3" )

The “31/3” year-end argument restarts the running total every 1 April. (Some locales need “03-31”.)

3. Previous year and growth

Sales LY      = CALCULATE ( [Total Sales], SAMEPERIODLASTYEAR ( Calendar[Date] ) )
Sales FYTD LY = CALCULATE ( [Sales FYTD], SAMEPERIODLASTYEAR ( Calendar[Date] ) )
FYTD Growth % = DIVIDE ( [Sales FYTD] - [Sales FYTD LY], [Sales FYTD LY] )

4. Visual setup

• FY on a slicer (single select); Month (sorted by FYMonthNo) or FYQuarter on axes.
• Always use Calendar columns in visuals, not the fact table’s date.
• For the current FY only: a filter on Calendar[FY] = the current FY label, or a relative date filter.

Where people go wrong

Practice with the four-table model from the Power BI course (download below); expected FY totals are included.